Subversion-Projekte sthq.argas

// Gave up on all that BehavED shit. Writing it by hand. Told VC++ its a C
// file to get colour coding (yea i know but i like colours).

// 22/01/06: Steve      : Fixed camera positions (offset +592 -2560 0)

//------------------------------------------------
// Brief rundown of script as of 22/01/06 - Steve
//------------------------------------------------
//Start music
//Set screen black
//Enable the camera
//Move it in front of the lift
//Set up kirk npc with boltons and camera group
//Set the camera to look at kirk
//Give the actual kirk the boltons (weapon ones not really needed)
//Fade out
//Start one bit of dialogue
//Start lift moving down
//After 4 seconds cut in new dialogue
//After 1 move the camera in front of kirk and zoom in a bit
//After 5 seconds start some more dialogue
//Wait 5 then do some more
//Open the shaft door
//Move camera below shaft
//zoom out to normal fov
//Wait 5 seconds then say final dialogue
//Close up of face
//Look around a bit
//Start getting weapon
//Hide npc
//Move player to npc position
//Disable camera and give weapons
//Get out phaser
//play "roaming" music

// Music
set ( "SET_CON_COMMAND", "music music/ae_02/kirk_descends.mp3 music/ae_02/kirk_descends.mp3" );

// Mysterious darkness
camera ( FADE, < 0.000 0.000 0.000 >, 1.000, < 0.000 0.000 0.000 >, 1.000, 0 );

// Enable Camera
camera ( ENABLE );


// Position camera in front of lift
camera ( MOVE, <-2147 -1621 2896>, 0 );
//camera ( MOVE, <-2739 939 2896>, 0 ); (offset +592 -2560 0)


set ( /*@SET_TYPES*/ "SET_VIDEO_PLAY", "sfx2" );
wait ( 200.000 );

affect ( "munro", /*@AFFECT_TYPE*/ INSERT )
{
        set ( /*@SET_TYPES*/ "SET_WEAPON", /*@WEAPON_NAMES*/ "WP_STASIS" );
        set ( /*@SET_TYPES*/ "SET_INVISIBLE", /*@BOOL_TYPES*/ "true" );
}



// Set up our npc ready for use
affect ( "kirk", FLUSH )
{
        set ( "SET_BOLTON_ON", "phaser_hip" );
        set ( "SET_BOLTON_ON", "tos_mini_tricorder_hip" );
        set ( "SET_BOLTON_ON", "communicator_hip" );
        set ( "SET_INVISIBLE", "false" );
        set ( "SET_CAMERA_GROUP", "kirkgrp" );

        // Look at the npc
        camera ( FOLLOW, "kirkgrp", 0.000, 0 );
}

// Give us all the right weapons and boltons
affect ( "munro", FLUSH)
{
        set ( "SET_BOLTON_ON", "phaser_hip" );
        set ( "SET_BOLTON_ON", "tos_mini_tricorder_hip" );
        set ( "SET_BOLTON_ON", "communicator_hip" )
}

// Give it all  a second to pull its head out
wait (1000.000 );

// Fade back to reality
camera ( FADE, < 0.000 0.000 0.000 >, 1.000, < 0.000 0.000 0.000 >, 0.000, 3000 );

// First bit
task ( "pro1" )
{
        sound ( CHAN_VOICE, "sound/voice/ae02/Kirk/prologue1.mp3" );
}
do ( "pro1" );

// Move down the lift with us watching
affect ( "lift", FLUSH )
{
        move ( $tag("lift_down", ORIGIN)$, <0 0 0>, 20000.000 );
}

// Five seconds later
wait (5000.000 );

// Second bit
task ( "pro2" )
{
        sound ( CHAN_VOICE, "sound/voice/ae02/Kirk/prologue2.mp3" );
}
do ( "pro2" );

// Wait a bit
wait (3000.000 );

// Second position, us in the lift too
affect ( "kirk", FLUSH )
{
        // 1664 is a magic number (sorry) that will just move along the vertical axis. It is
        // also a good year for beer.
        //camera( MOVE, get( VECTOR, "SET_ORIGIN" ), 1664 ) // Note 1664 is actually 0
    camera ( FOLLOW, "", 0.000, 1 );
        //camera ( /*@CAMERA_COMMANDS*/ MOVE, $TAG("lift_down", ANGLES)$, 0 );
        // 15001 is the same thing but the duration is set to 15000
        //camera ( MOVE, $tag("lift_down", ORIGIN)$, 15001 );
camera ( /*@CAMERA_COMMANDS*/ MOVE, $TAG("goingdown", ORIGIN)$, 0 );
camera ( /*@CAMERA_COMMANDS*/ PAN, $TAG("goingdown", ANGLES)$, < 0.000 0.000 0.000 >, 0 );
camera ( /*@CAMERA_COMMANDS*/ MOVE, $TAG("goingdown2", ORIGIN)$, 12000 );
camera ( /*@CAMERA_COMMANDS*/ PAN, $TAG("goingdown2", ANGLES)$, < 0.000 0.000 0.000 >, 12000 );

        // Zoom in closer
        Camera( ZOOM, 80, 0 );
}

// Not really needed but keeps it i sync with the camera
affect ( "lift", FLUSH )
{
        move ( $tag("lift_down", ORIGIN)$, <0 0 0>, 15000.000 );
}

// Wait 5 seconds
wait (5000.000 );

// Third sentence
task ( "pro3" )
{
        sound ( CHAN_VOICE, "sound/voice/ae02/Kirk/prologue3.mp3" );
}
do ( "pro3" );  // Lasts 4 seconds

// Wait whilst it does this
wait (4000.000 );

// Next bit
task ( "pro4" )
{
        sound ( CHAN_VOICE, "sound/voice/ae02/Kirk/prologue4.mp3" );
}
do ( "pro4" );  // Lasts 4 seconds

// Open the door
use ( "shaftdoor" );
wait (2000.000 );

// Move us out onto the floor in front of kirk
//camera ( MOVE, <-2172 -1586 -390>, 0 );
//camera ( MOVE, <-2764 974 -390>, 0 ); (offset +592 -2560 0)
camera( ZOOM, 80; 0 );
camera ( /*@CAMERA_COMMANDS*/ MOVE, $TAG("lift_arrive1", ORIGIN)$, 0 );
camera ( /*@CAMERA_COMMANDS*/ PAN, $TAG("lift_arrive1", ANGLES)$, 0 );
camera ( /*@CAMERA_COMMANDS*/ MOVE, $TAG("lift_arrive2", ORIGIN)$, 3000 );
camera ( /*@CAMERA_COMMANDS*/ PAN, $TAG("lift_arrive2", ANGLES)$, 3000 );



// Go back to normal FOV


// Wait 1 seconds to hit the ground
wait (1000.000 );

// Final bit
task ( "pro5" )
{
        sound ( CHAN_VOICE, "sound/voice/ae02/Kirk/prologue5.mp3" );
}
do ( "pro5" );  // Lasts 4 seconds

// One second dramatic pause
wait (6000.000 );

// Close up of face
Camera( ZOOM, 15, 0 );

// Look around
affect ( "kirk", FLUSH )
{
        set ( "SET_ANIM_BOTH", "BOTH_STAND1_RANDOM7" );
}

// For 6 seconds (minus a bit to stop it teleflagging)
wait (5500.000 );

task ( "pro6" )
{
        sound ( CHAN_VOICE, "sound/voice/ae02/Kirk/prologue6.mp3" );
}
do ( "pro6" );  // Lasts 4 seconds
wait ( 4000.000 );


// Get his weapon out (oh do grow up)
affect ( "kirk", FLUSH )
{
        set ( "SET_ANIM_UPPER", "TORSO_RAISEWEAP1" );
}

// Give it a bit to show some movement
wait (1000.000 );

// Make kirk invisable
affect ( "kirk", FLUSH )
{
        set ( "SET_INVISIBLE", "true" );
}
// Not entirely sure why this is here.. so remove it
//camera ( MOVE, <-2839 873 2896>, 0 );

// Move player to where kirk is
set ( "SET_CON_COMMAND", "setviewpos -2236 -1687 -416 45" );
//set ( "SET_CON_COMMAND", "setviewpos -2828 873 -416 45" );  (offset +592 -2560 0)
// Dont need this, have setviewpos now
//affect ( "munro", FLUSH )
//{
//      move ( <-2828 873 -416>, <0 0 0>, 0 );
//}

// Turn it off
camera ( DISABLE );

// Give him the weapons
affect ( "munro", FLUSH)
{
        set ( "SET_WEAPON", "WP_PHASER" );
        set ( "SET_WEAPON", "WP_TRICORDER" );
        set ( "SET_WEAPON", "WP_STASIS" );
        set ( "SET_WEAPON", "WP_COMPRESSION_RIFLE" );
}

// Get his phaser out (i said grow up)
set ( "SET_CON_COMMAND", "weapon 2" );

// Music
set ( "SET_CON_COMMAND", "music music/ae_02/deserted_facility.mp3 music/ae_02/deserted_facility.mp3" );