Subversion-Projekte sthq.gbs

//  EF2 Level Script File
//
//  Level:              map2a.bsp
//  Script By:          Argyle, LTiefland & DrBob 
//  Geometry By:        Argyle, LTiefland & DrBob
//  Created on:         Unknown
//  Last Edited:        13/03/04
//  Last Edited By:     LTiefland

#include "maps/global_scripts/global_common.scr"


void remote_guy_onUse()
{
        //You are trying to talk to the remote guy, so make him give you a rude retort ;)
        $remote_guy.playdialog("localization/sound/dialog/m2l1/teacherm2_busy.mp3", 1, 256, 0);
        waitfordialog( $remote_guy );
}

void repair_lady_onUse()
{
        //You are trying to talk to the repair lady, so make her give you a rude retort ;)
        $repair_lady.playdialog("localization/sound/dialog/m2l1/teacherf2_time.mp3", 1, 256, 0);
        waitfordialog( $repair_lady );
}

void hovercar()
{

   
        $hovercar_crate1.bind($hovercar_origin);
        $hovercar_crate2.bind($hovercar_origin);
        $hovercar_crate3.bind($hovercar_origin);
        $hovercar_crate4.bind($hovercar_origin);
        $hovercar_crate5.bind($hovercar_origin);
        $hovercar_crate6.bind($hovercar_origin);
        $hovercar_sound.bind($hovercar_origin);   
        $hovercar.bind($hovercar_origin);

        wait(0.5);
   
        $hovercar_origin.time(5);
        $hovercar_origin.moveto($hovercar_origin2);
        waitfor($hovercar_origin);
        $hovercar_origin.time(3);
        $hovercar_origin.rotateYdown(90);
        wait(3.5);
   
        $hovercar_origin.time(5);
        $hovercar_origin.moveto($hovercar_origin3);
        wait(3);
        $remote_guy.anim("idle");
        $remote_guy.walkto("$remote_guy_1");
        waitfor($remote_guy); 
        $remote_guy.anim( "ent-datapad-use" );
}

void remote_scene()
{
        thread hovercar();
}

void moya_cin()
{
        $moya.walkto("$moya_4");
        waitfor($moya);
        $moya.walkto("$moya_5");
        waitfor($moya);
        $moya.walkto("$moya_7");
        waitfor($moya);
        $door1.open($door1);
        $moya.walkto("$moya_8");
        waitfor($moya);
        $door1.close();
        $door1.lock();
        $moya.walkto("$moya_10");
        waitfor($moya);
        $moya.hide();
        $moya.notsolid();
}

void hazard_cin()
{
        freezeplayer();
        cinematic();
        letterbox(.1);
        spawn("camera","targetname","map2_cam1");
        wait(.5);
        $map2_cam1.follow($map2_hazard_cin_1);
        cuecamera($map2_cam1);
        $munro.walkto("$nav_transroom1");
        $kourban.walkto("$nav_transroom2");
        $gonzales.walkto("$nav_transroom3");
        wait(3);
        waitfor($munro);
        $munro.walkto("$nav_plat1");
        $kourban.walkto("$nav_plat2");
        $gonzales.walkto("$nav_plat3");
        waitfor($kourban);
        $mankell.playdialog("localization/sound/dialog/map02/mankell/nicetohaveyou.mp3",1,10000,0);
        waitfordialog($mankell);
        $mankell.playdialog("localization/sound/dialog/map02/mankell/greet.mp3",1,10000,0);
        waitfordialog($mankell);
        $munro.playdialog("localization/sound/dialog/map02/munro/ayesir.mp3",1,10000,0);
        waitfordialog($munro);
        wait(2);
        $kourban.displayEffect( "TransportOut", "Federation" );
        $gonzales.displayEffect( "TransportOut", "Federation" );
        $munro.displayEffect( "TransportOut", "Federation" );
        wait(2);
        $kourban.notsolid();
        $gonzales.notsolid();
        $munro.notsolid();
        $mankell.walkto("$mankell_2");
        waitfor($mankell);
        clearletterbox(.1);
        noncinematic();
        releaseplayer();
        cueplayer();
        $mankell.walkto("$mankell_4");
        waitfor($mankell);
        $mankell.walkto("$mankell_7");
        waitfor($mankell);
        $mankell.walkto("$mankell_9");
        waitfor($mankell);
        $mankell.hide();
        $mankell.notsolid();
}

void main()
{
        //Setup people's use threads
        thread globalCommon_OnUse( $remote_guy , "remote_guy_onUse" );
        thread globalCommon_OnUse( $repair_lady, "repair_lady_onUse" );

        soundtrack( "m2l3-sfa.mus" );
        $munro.ai_off();
        $munro.pushable( 0 );
        $kourban.ai_off();
        $kourban.pushable( 0 );
        $gonzales.ai_off();
        $gonzales.pushable( 0 );
        $repair_lady.ai_off();
        $repair_lady.pushable( 0 );
        $remote_guy.ai_off();
        $remote_guy.pushable( 0 );
        $moya.ai_off();
        $moya.pushable( 0 );
        $mankell.ai_off();
        $mankell.pushable( 0 );

        //Anims
        $repair_lady.anim("cin-m3_hunch");
        $remote_guy.useactorweapon( "EnterpriseDatapad" );
        $remote_guy.anim( "ent-datapad-use" );

        $gonzales.removeactorweapon ( "CompressionRifle" );
        $munro.removeactorweapon ( "CompressionRifle" );
        $kourban.removeactorweapon ( "AssaultRifle" );
        wait(1);
        moya_cin();
}

void surprise()
{
}